On this page

• Introduction
• Prerequisites
• List of hardware
• Wiring
  • SIM808 shield connection
  • HTU21D connection
• Complete wiring
  • Device provisioning
  • Provision your dashboard
  • Creating Arduino firmware
    • Step 1. Arduino UNO and Arduino IDE setup.
    • Step 2. Install Arduino IoT Hub SDK and dependencies
    • Step 3. Install HTU21D library
    • Step 4. Install SIM808 driver
    • Step 5. Prepare and upload a sketch.
  • Troubleshooting
  • Data visualization

Introduction

IoT Hub is an open-source server-side platform that allows you to monitor and control IoT devices. It is free for both personal and commercial usage and you can deploy it anywhere. If this is your first experience with the platform we recommend to review what-is-iothub page and getting-started guide.

This sample application performs collection of humidity and temperature values produced by HTU21D sensor and further visualization on the real-time web dashboard. Collected data is pushed via HTTP to IoT Hub server for storage and visualization. The purpose of this application is to demonstrate IoT Hub data collection API and visualization capabilities.

The HTU21D sensor is connected to Arduino UNO. Arduino UNO connects to the Internet using SIM808 GSM shield. Arduino UNO pushes data to IoT Hub server via HTTP protocol by using Arduino IoT Hub SDK. Data is visualized using built-in customizable dashboard. The application that is running on Arduino UNO is written using Arduino SDK which is quite simple and easy to understand.

Once you complete this sample/tutorial, you will see your sensor data on the following dashboard.

Prerequisites

You will need to have IoT Hub server up and running. The easiest way is to use Live Demo server.

The alternative option is to install IoT Hub using Installation Guide. Windows users should follow this guide. Linux users that have docker installed should execute the following commands:

1
2
3
4
5
mkdir -p ~/.mytb-data && sudo chown -R 799:799 ~/.mytb-data
mkdir -p ~/.mytb-logs && sudo chown -R 799:799 ~/.mytb-logs
docker run -it -p 9090:9090 -p 7070:7070 -p 1883:1883 -p 5683-5688:5683-5688/udp -v ~/.mytb-data:/data \
-v ~/.mytb-logs:/var/log/thingsboard --name mytb --restart always thingsboard/tb-postgres

These commands install IoT Hub and load demo data and accounts.

IoT Hub UI will be available using the URL: http://localhost:8080. You may use username tenant@thingsboard.org and password tenant. More info about demo accounts is available here.

List of hardware

• Arduino UNO

  

• HTU21D sensor

  

• SIM808 GSM shield

  

Wiring

SIM808 shield connection

Simply connect SIM808 shield on top of your Arduino.

HTU21D connection

Connect HTU21D in following manner:

• VCC - Arduino 3.3V
• GND - Arduino GND
• SDA - Arduino A5
• SCL - Arduino A4

Complete wiring

Double-check that your wiring follows schematics below:

The complete setup will look like that:

Device provisioning

This step contains instructions that are necessary to connect your device to IoT Hub.

Open IoT Hub Web UI (http://localhost:8080) in browser and login as tenant administrator. If you loaded the demo data during TB installation, the next credentials can be used:

• login: tenant@thingsboard.org
• password: tenant

Go to “Devices” section. Click “+” button and create a device with the name “Arduino UNO Demo Device”. Set “Device type” to “default”.

Once device created, open its details and click “Manage credentials”.

Copy auto-generated access token from the “Access token” field. Please save this device token. It will be referred to later as $ACCESS_TOKEN.

Provision your dashboard

Download the dashboard file using this link. Use import/export instructions to import the dashboard to your IoT Hub instance.

Creating Arduino firmware

If you already familiar with basics of Arduino UNO programming using Arduino IDE you can skip the following step and proceed with step 2.

Step 1. Arduino UNO and Arduino IDE setup.

In order to start programming the Arduino UNO device, you will need Arduino IDE and all related software installed.

Download and install Arduino IDE.

To learn how to connect your Uno board to the computer and upload your first sketch please follow this guide.

Step 2. Install Arduino IoT Hub SDK and dependencies

To simplify application development, install the IoT Hub Arduino SDK and its dependencies from standard Arduino library repository:

1. Proceed to Sketch -> Include Library… submenu. Select Manage Libraries.

2. Find and install IoT Hub Arduino SDK and PubSubClient by Nick O’Leary libraries.

   

3. Install ArduinoJSON library v6.9.1 or higher. Avoid installing beta releases of the ArduinoJson library.

   

4. Install ArduinoHttpClient library.

   

From now on, you can use IoT Hub SDK right from Arduino IDE.

Step 3. Install HTU21D library

Use SparkFun HTU21D library, as shown in the screenshot below.

Step 4. Install SIM808 driver

The SIM808 is support by the TinyGSM driver, which can be installed as described below.

Step 5. Prepare and upload a sketch.

Download and open arduino_htu21d_sim808_http.ino sketch.

Note You need to edit following constants and variables in the sketch:

• apn - GPRS access point name. Consult your cellular network provider to get more information.
• user - GPRS access point user. Consult your cellular network provider to get more information.
• pass - GPRS access point password. Consult your cellular network provider to get more information.
• TOKEN - the $ACCESS_TOKEN from IoT Hub configuration step.
• THINGSBOARD_SERVER - IoT Hub HOST/IP address that is accessible from within your wifi network. Specify “iothub.magenta.at” if you are using live demo server.
• THINGSBOARD_PORT - HTTP port to connect to. Change it if necessary.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
// This sketch demonstrates connecting and sending telemetry
// usingIoT Hub SDK and GSM modem, such as SIM808
//
// Hardware:
//  - Arduino Uno
//  - SIM808 Arduino shield connected to Arduino Uno

// Select your modem:
//#define TINY_GSM_MODEM_SIM800
 #define TINY_GSM_MODEM_SIM808
// #define TINY_GSM_MODEM_SIM900
// #define TINY_GSM_MODEM_UBLOX
// #define TINY_GSM_MODEM_BG96
// #define TINY_GSM_MODEM_A6
// #define TINY_GSM_MODEM_A7
// #define TINY_GSM_MODEM_M590
// #define TINY_GSM_MODEM_ESP8266

#include <TinyGsmClient.h>
#include <SoftwareSerial.h>
#include <SparkFunHTU21D.h>
#include "ThingsBoard.h"

// Your GPRS credentials
// Leave empty, if missing user or pass
const char apn[]  = "internet";
const char user[] = "";
const char pass[] = "";

// See https://iothub.magenta.at/docs/getting-started-guides/helloworld/
// to understand how to obtain an access token
#define TOKEN               "YOUR_ACCESS_TOKEN"
#define THINGSBOARD_SERVER  "iothub.magenta.at"
#define THINGSBOARD_PORT    80

// Baud rate for debug serial
#define SERIAL_DEBUG_BAUD   115200

// Serial port for GSM shield
SoftwareSerial serialGsm(7, 8); // RX, TX pins for communicating with modem

// Uncomment to see StreamDebugger output in serial monitor
//#define DUMP_AT_COMMANDS 1

#ifdef DUMP_AT_COMMANDS
  #include <StreamDebugger.h>
  StreamDebugger debugger(serialGsm, Serial);
  TinyGsm modem(debugger);
#else
  // Initialize GSM modem
  TinyGsm modem(serialGsm);
#endif

// Initialize GSM client
TinyGsmClient client(modem);

// InitializeIoT Hub instance
ThingsBoardHttp tb(client, TOKEN, THINGSBOARD_SERVER, THINGSBOARD_PORT);

// Set to true, if modem is connected
bool modemConnected = false;

HTU21D sensor;

void setup() {
  // Set console baud rate

  Serial.begin(SERIAL_DEBUG_BAUD);
  Serial.println("-------SETUP------");

  // Set GSM module baud rate
  serialGsm.begin(115200);
  delay(3000);

  // Lower baud rate of the modem.
  // This is highly practical for Uno board, since SoftwareSerial there
  // works too slow to receive a modem data.

  serialGsm.write("AT+IPR=9600\r\n");
  serialGsm.end();
  serialGsm.begin(9600);

  // Restart takes quite some time
  // To skip it, call init() instead of restart()
  Serial.println(F("Initializing modem..."));
  modem.restart();

  String modemInfo = modem.getModemInfo();
  Serial.print(F("Modem: "));
  Serial.println(modemInfo);

  sensor.begin();

  // Unlock your SIM card with a PIN
  //modem.simUnlock("1234");
}

void loop() {
  delay(1000);

  if (!modemConnected) {
    Serial.print(F("Waiting for network..."));
    if (!modem.waitForNetwork()) {
        Serial.println(" fail");
        delay(10000);
        return;
    }
    Serial.println(" OK");

    Serial.print(F("Connecting to "));
    Serial.print(apn);
    if (!modem.gprsConnect(apn, user, pass)) {
        Serial.println(" fail");
        delay(10000);
        return;
    }

    modemConnected = true;
    Serial.println(" OK");
  }

  // Uploads new telemetry toIoT Hub using HTTP.
  // See https://iothub.magenta.at/docs/reference/http-api/#telemetry-upload-api
  // for more details

  Serial.println("Sending temperature data...");
  tb.sendTelemetryFloat("temperature", sensor.readTemperature());

  Serial.println("Sending humidity data...");
  tb.sendTelemetryFloat("humidity", sensor.readHumidity());
}

Connect your Arduino UNO device via USB cable and select “Arduino/Genuino Uno” port in Arduino IDE. Compile and Upload your sketch to the device using “Upload” button.

After application will be uploaded and started it will try to connect to IoT Hub node using HTTP and upload “humidity” and “temperature” timeseries data once per second.

Troubleshooting

When the application is running you can select “Arduino/Genuino Uno” port in Arduino IDE and open “Serial Monitor” in order to view debug information produced by serial output.

Data visualization

Finally, open IoT Hub Web UI. You can access this dashboard by logging in as a tenant administrator. Use

• login: tenant@thingsboard.org
• password: tenant

in case of local IoT Hub installation.

Go to “Devices” section and locate “Arduino UNO Demo Device”, open device details and switch to “Latest telemetry” tab. If all is configured correctly you should be able to see latest values of humidity and temperature in the table.

After, open “Dashboards” section then locate and open “dashboard Arduino Uno with SIM808 Shield and HTU21D sensor”. As a result, you will see two time-series charts and digital gauges displaying humidity and temperature level (similar to dashboard image in the introduction).